スクロール領域生成モジュール【一応完成】

いままでバグがありましたが、完全に取り払うことができました！ついでに、サイズ変更機能はいらないんじゃないかなぁと思い、サイズ変更BOXスタイル（WS_SIZEBOX）をとりました。SetWindowLongAの行です。
cookies146
2011/10/1 17:25
タグ：
hsp
スクロール
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
#module "scrlbar"
/*Cookies wrote:
http://fs-cgi-basic01.freespace.jp/~hsp/ver3/hsp3.cgi?print+200511/05110003.txtからの転載
http://quasiquote.org/hspwiki/%E3%82%A6%E3%82%A4%E3%83%B3%E3%83%89%E3%82%A6%E3%81%AB%E3%82%B9%E3%82%AF%E3%83%AD%E3%83%BC%E3%83%AB%E3%83%90%E3%83%BC%E3%82%92%E4%BB%98%E3%81%91%E3%82%8B
を参考に。
この行から下に23行目のところ、編集させていただきました。*/
//-----------------------
#uselib "user32"
#func   GetWindowLongA "GetWindowLongA" int,int
#func   SetWindowLongA "SetWindowLongA" int,int,int
#func   ShowScrollBar  "ShowScrollBar"  int,int,int
#func   SetScrollInfo  "SetScrollInfo"  int,int,var,int
#func   SetScrollPos   "SetScrollPos"   int,int,int,int
#func   SetWindowPos   "SetWindowPos"   int,int,int,int,int,int,int
//-----------------------
// 水平 垂直スクロールバーを使えるようにする
#deffunc ScrollBar 
 oncmd gosub *WMSIZE,   5
 oncmd gosub *SCROLL,   $114
 oncmd gosub *SCROLL,   $115
        si= 28, 31, 0,0,0,0,0   // SCROLLINFO構造体
        wx.ginfo_sel= ginfo_sizex+ginfo_sx-ginfo_winx
        wy.ginfo_sel= ginfo_sizey+ginfo_sy-ginfo_winy
;                                     WS_VSCROLL|WS_HSCROLL|WS_SIZEBOX
        GetWindowLongA hwnd,-16 : SetWindowLongA hwnd,-16,stat|$340000   ^ 0x00040000 //^以降変更(WS_SIZEBOXはいらないでしょ？)
        
        SetWindowPos hWnd, 0, 0, 0, 0, 0, $37 ; screen 0, bgscr用        
        return 1
*WMSIZE //ウィンドウサイズが変更された時の処理
        sel=ginfo_sel : gsel ginfo_intid
        repeat 2
                si.3= ginfo(26+cnt), ginfo(12+cnt), ginfo(8+cnt)
                SetScrollInfo hWnd, cnt, si, 1
        loop
        groll ginfo_vx, ginfo_vy
        mref bm,67 : bm.20=ginfo_winx, ginfo_winy
        hHide= wx.ginfo_intid= ginfo_sizex ;gsel selを確実に実行させるため
        vHide= wy.ginfo_intid= ginfo_sizey
        wnd=hwnd : gsel sel ;何故かスクロールバーが描画されない環境があるため
        if hHide=1: ShowScrollBar wnd, 0, 0:else: SetWindowPos Wnd, 0,0,0,0,0,$37
        if vHide=1: ShowScrollBar wnd, 1, 0:else: SetWindowPos Wnd, 0,0,0,0,0,$37
        return 1
*SCROLL //スクロールバー操作時の処理
        sel=ginfo_sel : gsel ginfo_intid
        m=iparam=$115 : nPos=ginfo(8+(m=1))
        Code= wParam &$ffff
        repeat 1
                if Code= 5 : nPos=wParam>>16&$ffff : break ;TB_THUMBTRACK
                if Code= 0 : nPos-4     : break            ;TB_LINEUP
                if Code= 1 : nPos+4     : break
                if Code= 2 : nPos-32: break
                if Code= 3 : nPos+32
        loop
        SetScrollPos hWnd, m, nPos, 1
        if m : groll ginfo_vx, nPos :else: groll nPos, ginfo_vy
        gsel sel : return 1
#global
;-----------------------
#module "scrlbar_iframe"
#uselib "USER32.DLL"
#func SetParent "SetParent" int,int
#cfunc GetSystemMenu "GetSystemMenu" int, int
#func DeleteMenu "DeleteMenu" int, int, nullptr
#deffunc iframe_ int wid_, int wxsize, int wysize, int sxsize, int sysize
    wid=wid_ : if wid=-1 : wid = ginfo_newid
    hpwnd=hwnd
    
    bgscr wid, wxsize, wysize, 2, ginfo_cx, ginfo_cy, sxsize, sysize
    SetParent hwnd, hpwnd
    ScrollBar
    gsel wid, 1
return wid
#define global iframe(%1=-1, %2=640, %3=480, %4=640, %5=480) iframe_ %1,%2,%3,%4,%5
#global
//StyleAdd ハンドル,スタイル,追加(0)or削除(1) (+2で 拡張ウィンドウスタイル)
#uselib "user32.dll"
#func  global SetLong "SetWindowLongA" int, int, int
#cfunc global GetLong "GetWindowLongA" int, int
#define global StyleAdd(%1, %2=0, %3=0)ujw=((%3)&2)*-2-16 :\
        SetLong %1, ujw, GetLong(%1, ujw)|(%2)^((%3)&1)*(%2)
#define 拡張 2
#define 削除 1
;-----------------------
onexit gosub *owari
screen 0
        title "screen 0"
        picload dir_exe+"\\sample\\hspdx\\HSPDX.BMP"
        ScrollBar
        width 400, 300
pos 10, 20
iframe , 640, 480, 100, 100
        title "サイズ変更してみてください(^^)v"
        picload dir_exe+"/sample/demo/JP6GIRL.BMP",1
        stop
        
*owari
        if iparam|wparam=0:end
        wait 20:gsel wparam, -1:return
XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
このコードをツイートする